İRC PAYLASİM www.ircpaylasim.tr.gg

http://ircpaylasim.tr.gg

İRCPAYLASİM SIK KULLANILANLARA EKLE!
   
  İRc Paylaşım
  PnP Progress Bar
 

Çoğumuz PnP 'yi bilir. Her ne kadar şuan da 10 'larca script olmasına rağmen en azından eskiler PnP 'nin Profesyonelliğinden haberdardır Ben de eski bir PnP hayranıyım. Belki size görsellik o kadar çok şey kazandırmaz. Ama Kodların içine daldığınızda nasıl bir sanatla karşı karşıya kaldınız o zaman anlarsınız...

Neyse uzun lafın kısası

Kod kullanımı çok basit. Progress Bar 'ı açmak için:

Kod:
_progress.1 Script Yüklemesi Başlıyor...



Bu Progress Barın açılışı... Yalnızca "_progress.1 [Progress Bar Başlığı]" Şeklinde...

Kod:
_progress.2 10 YouTube 'a bağlanılıyor...



Bu kısım da artık "_progress.2 [Yüzdelik Dilim] [Alt Başlık]" Şeklinde kullanımı var. Yüzdelik dilim olarak ne seçerseniz Progress Bar O kısma kadar Durumu Dolduracaktır.

Kod:
_progress.2 60 Video Bulundu! Şimdi indiriliyor...

Kod:
_progress.2 100 Script Yüklendi..



Progress Bar %100 olduğunda otomatik olarak kendini kapatıyor..

Gördüğünüz gibi kullanımı oldukça basit. Peki bu scriptte ne kullanıldı? DLL? Image Gradient? Hayır! Sadece mIRC Draw

Yüklemek için sadece aşağıdaki kodu remoteye koyun ve kaydedin.

Kod:
alias _progress.1 {
  close -@ @Progress @.pbmp
  window -pfdohkaBz +bLt @Progress $calc($window(-1).w - 330) $calc($window(-1).h - 160) 319 104
  drawrect -frn @Progress $rgb(face) 2 0 0 319 104
  _gradient @Progress 9 69 300 25
  _bevel @Progress 7 67 304 29
  drawrect -rn @Progress $rgb(face) 7 0 60 319 44
  drawtext -nr @Progress $rgb(text) "ms sans serif" 16 8 25 $1-
 ; Progress Barın sağ köşesine image koyabilirsiniz 64 X 64
 ; drawpic -nt @Progress $rgb(255,255,255) 247 1 195 65 64 64 image.ico
  drawdot @Progress
  window -hpf @.pbmp 0 0 301 30
  drawcopy @Progress 9 69 300 28 @.pbmp 0 0
}
alias _progress.2 {
  if ($window(@Progress) == $null) return
  if ($1 > 100) { _recurse _progress.2 100 $2- | return }
  drawcopy -n @.pbmp 0 0 300 28 @Progress 9 69
  drawtext -nro @Progress $rgb(text) "arial" 24 $calc(159 - $width($1%,arial,24,1,0) / 2) 67 $1%
  drawrect -nrif @Progress 1 0 9 69 $calc($1 * 3 + 1) 26
  drawrect -frn @Progress $rgb(face) 2 8 45 236 21
  drawtext -cnr @Progress $rgb(text) "ms sans serif" 12 8 48 235 99 $2-
  titlebar @Progress - $1%
  drawdot @Progress
  if ($1 == 100) {
    .timer.kill.progress -mio 1 500 close -@ @Progress @.pbmp $chr(124)
  }
}
alias -l _bevel {
  drawrect -nr $1 $rgb(frame) 1 $calc($2 + 1) $calc($3 + 1) $calc($4 - 1) $calc($5 - 1)
  drawrect -frn $1 $rgb(3dlight) 2 $calc($2 + 1) $calc($3 + $5 - 1) $calc($4 - 1) 2
  drawrect -frn $1 $rgb(3dlight) 2 $calc($2 + $4 - 1) $calc($3 + 1) 2 $calc($5 - 1)
  drawrect -nr $1 $rgb(hilight) 1 $2 $3 $calc($4 + 1) $calc($5 + 1)
  drawline -nr $1 $rgb(shadow) 1 $2 $calc($3 + $5 - 1) $2 $3 $calc($2 + $4) $3
}
alias -l _gradient {
  var %place = $calc($4 / 2 + $5 / 2 + $2),%r = $calc($rgb(face) % 256),%g = $calc($rgb(face) / 256 % 256),%b = $calc($rgb(face) / 65536)
  :loopL
  drawline -nr $1 $rgb(%r,%g,%b) 7 $calc(%place - 3) $calc($3 - 3) $calc(%place - $5) $calc($3 + $5)
  if (%place > $2) {
    if (%r > 2) dec %r 3
    if (%g > 2) dec %g 3
    if (%b > 2) dec %b 3
    dec %place 8
    goto loopL
  }
  %place = $calc($4 / 2 + $5 / 2 + $2)
  %r = $calc($rgb(face) % 256)
  %g = $calc($rgb(face) / 256 % 256)
  %b = $calc($rgb(face) / 65536)
  var %goal = $calc($2 + $4 + $5)
  :loopR
  drawline -nr $1 $rgb(%r,%g,%b) 7 $calc(%place - 3) $calc($3 - 3) $calc(%place - $5) $calc($3 + $5)
  if (%place < %goal) {
    if (%r < 250) inc %r 3
    if (%g < 250) inc %g 3
    if (%b < 250) inc %b 3
    inc %place 8
    goto loopR
  }
}
alias _recurse $1- | return $result
 
  Bugün 21 ziyaretçi (119 klik) kişi burdaydı! (2008-2020 © Copyright By ircpaylasim ® Tüm Hakları saklıdır)  
 
Bu web sitesi ücretsiz olarak Bedava-Sitem.com ile oluşturulmuştur. Siz de kendi web sitenizi kurmak ister misiniz?
Ücretsiz kaydol